VBA入門
ピボットテーブル（PivotTable）

ExcelマクロVBAの基本と応用、エクセルVBAの初級・初心者向け解説
公開日：2013年5月以前　最終更新日：2021-11-02

第93回.ピボットテーブル（PivotTable）


マクロ VBA ピボットテーブル PivotTable

ピボットテーブルをマクロVBAで操作する事が良いかどうか、少々疑問な部分もあります。
しかし、ピボットテーブル（PivotTable）はエクセルでは必須機能になりますので、
少なくとも、ピボットテーブルの基本くらいは知っておくべきでしょう。


今回はピボットテーブル（PivotTable）のオブシェクトをざっと見てから、
その後は文法解説は少なめにして、マクロ記録で作成されたVBAをからスタートし、
実践的に使い回せるビボットテーブルのVBAコードを作成しつつ説明をしていきます。


ピボットテーブル（PivotTable）を構成するオブジェクト群

PivotCachesコレクション
PivotCacheオブジェクトのコレクション

PivotCacheオブジェクト
ピボットテーブル レポートのキャッシュ メモリを表します。

PivotTablesコレクション
PivotTableオブジェクトのコレクション

PivotTableオブジェクト
ワークシートにあるピボットテーブル レポートを表します。

PivotFieldsコレクション
PivotFieldオブジェクトのコレクション

PivotFieldオブジェクト
ピボットテーブル レポートのフィールドを表します。

これらのコレクション、オブジェクトに、それぞれのプロパティとメソッドがあります。
ピボットテーブル関連のプロパティ、メソッド一覧
・PivotCachesコレクション ・・・ PivotCacheオブジェクトのコレクション ・PivotCacheオブジェクト ・・・ ピボットテーブル レポートのキャッシュ メモリを表します ・PivotTablesコレクション ・・・ PivotTableオブジェクトのコレクション ・PivotTableオブジェクト ・・・ ワークシートにあるピボットテーブル レポートを表します ・PivotFieldsコレクション ・・・ PivotFieldオブジェクトのコレクション ・PivotFieldオブジェクト ・・・ ピボットテーブル レポートのフィールドを表します
上の一覧をご覧いただければわかりますが、膨大な量のプロパティ、メソッドがあります。
そして、決してこれで全てではありません>
さらに下位のオブジェクは他にもたくさんあります。
これらを覚えることはほぼ無理ですし、覚えることに意味はありません。

プロパティの設定値やメソッドの引数について知りたい場合は、
マクロの記録で自動記録されたVBAコードを参考にするのが最も早く簡単でしょう。

以下では、実践的なサンプでの説明をしていきます。
実践のVBAコードを読むことで、理解を深めて下さい。


A1セルからC10セルにデータが入っている表があるとします。


マクロ VBA ピボットテーブル

この表を元に、マクロ記録を行ってみます。


Excel2010のピボットテーブル（PivotTable）のマクロ記録

Sub Macro1()
　　Sheets.Add
　　ActiveWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:= _
　　　　"Sheet1!R1C1:R10C3", Version:=xlPivotTableVersion14).CreatePivotTable _
　　　　TableDestination:="Sheet4!R3C1", TableName:="ﾋﾟﾎﾞｯﾄﾃｰﾌﾞﾙ1", DefaultVersion _
　　　　:=xlPivotTableVersion14
　　Sheets("Sheet4").Select
　　With ActiveSheet.PivotTables("ﾋﾟﾎﾞｯﾄﾃｰﾌﾞﾙ1").PivotFields("担当")
　　　　.Orientation = xlRowField
　　　　.Position = 1
　　End With
　　With ActiveSheet.PivotTables("ﾋﾟﾎﾞｯﾄﾃｰﾌﾞﾙ1").PivotFields("分類")
　　　　.Orientation = xlColumnField
　　　　.Position = 1
　　End With
　　ActiveSheet.PivotTables("ﾋﾟﾎﾞｯﾄﾃｰﾌﾞﾙ1").AddDataField ActiveSheet.PivotTables( _
　　　　"ﾋﾟﾎﾞｯﾄﾃｰﾌﾞﾙ1").PivotFields("金額"), "合計 / 金額", xlSum
End Sub

このまま使えなくはありませんが、
シート名やピボットテーブル名が固定になっていますので、
整理して、使いまわせるように変更します。

いきなり非常に長い一文から始まっています。

ActiveWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:= _
　　　　"Sheet1!R1C1:R10C3", Version:=xlPivotTableVersion14).CreatePivotTable _
　　　　TableDestination:="Sheet4!R3C1", TableName:="ﾋﾟﾎﾞｯﾄﾃｰﾌﾞﾙ1", DefaultVersion _
　　　　:=xlPivotTableVersion14

この部分がわかりづらいと思います。
PivotCachesの作成と、CreatePivotTableでのピボットテーブルの作成を同時に行っている為です。
そこで、下のマクロでは、これを2段に分けて、
それぞれのオブジェクト変数に入れて使っています。

Sub Macro1()
　　Dim ws As Worksheet
　　Dim pvc As PivotCache
　　Dim pvt As PivotTable
　　Set ws = Sheets.Add
　　Set pvc = ActiveWorkbook.PivotCaches.Create(SourceType:=xlDatabase, _
　　　　　　　　　　　　　　　　　　　　　　　　SourceData:="Sheet1!R1C1:R10C3", _
　　　　　　　　　　　　　　　　　　　　　　　　Version:=xlPivotTableVersion14)
　　Set pvt = pvc.CreatePivotTable(TableDestination:=ws.Name & "!R3C1", _
　　　　　　　　　　　　　　　　　　　　　　　　TableName:="ﾋﾟﾎﾞｯﾄﾃｰﾌﾞﾙ1", _
　　　　　　　　　　　　　　　　　　　　　　　　DefaultVersion:=xlPivotTableVersion14)
　　With pvt
　　　　With .PivotFields("担当")
　　　　　　.Orientation = xlRowField
　　　　　　.Position = 1
　　　　End With
　　　　With .PivotFields("分類")
　　　　　　.Orientation = xlColumnField
　　　　　　.Position = 1
　　　　End With
　　　　.AddDataField .PivotFields("金額"), "合計 / 金額", xlSum
　　End With
End Sub

だいぶ理解しやすいのではないかと思います。

Set pvc = ActiveWorkbook.PivotCaches.Create(
ブックにピボットキャッシュを作成しています。

Set pvt = pvc.CreatePivotTable(
ピボットキャッシュにピボットテーブルを作成しています。


Excel2003のピボットテーブル（PivotTable）のマクロ記録

Sub Macro2()
　　Range("A1").Select
　　ActiveWorkbook.PivotCaches.Add(SourceType:=xlDatabase, SourceData:= _
　　　　"Sheet1!R1C1:R10C3").CreatePivotTable TableDestination:="", TableName:= _
　　　　"ﾋﾟﾎﾞｯﾄﾃｰﾌﾞﾙ1", DefaultVersion:=xlPivotTableVersion10
　　ActiveSheet.PivotTableWizard TableDestination:=ActiveSheet.Cells(3, 1)
　　With ActiveSheet.PivotTables("ﾋﾟﾎﾞｯﾄﾃｰﾌﾞﾙ1").PivotFields("担当")
　　　　.Orientation = xlRowField
　　　　.Position = 1
　　End With
　　With ActiveSheet.PivotTables("ﾋﾟﾎﾞｯﾄﾃｰﾌﾞﾙ1").PivotFields("分類")
　　　　.Orientation = xlColumnField
　　　　.Position = 1
　　End With
　　ActiveSheet.PivotTables("ﾋﾟﾎﾞｯﾄﾃｰﾌﾞﾙ1").AddDataField ActiveSheet.PivotTables( _
　　　　"ﾋﾟﾎﾞｯﾄﾃｰﾌﾞﾙ1").PivotFields("金額"), "合計 / 金額", xlSum
End Sub

こちらの方が2010よりは理解しやすいかもしれません。
このまま使えなくはありませんが、
シート名やピボットテーブル名が固定になっていますので、
整理して、使いまわせるように変更します。

Excel2010のマクロ記録同様に、長い一文から始まっています。

ActiveWorkbook.PivotCaches.Add(SourceType:=xlDatabase, SourceData:= _
　　　　"Sheet1!R1C1:R10C3").CreatePivotTable TableDestination:="", TableName:= _
　　　　"ﾋﾟﾎﾞｯﾄﾃｰﾌﾞﾙ1", DefaultVersion:=xlPivotTableVersion10

この部分がわかりづらいと思います。
PivotCachesの作成と、CreatePivotTableでのピボットテーブルの作成を同時に行っている為です。

そこで、下のマクロでは、これを２段に分けて、
それぞれのオブジェクト変数に入れて使っています。

Sub Macro2()
　　Dim ws As Worksheet
　　Dim pvc As PivotCache
　　Dim pvt As PivotTable
　　Set ws = Sheets.Add
　　Set pvc = ActiveWorkbook.PivotCaches.Add(SourceType:=xlDatabase, _
　　　　　　　　　　　　　　　　　　　　　　SourceData:="Sheet1!R1C1:R10C3")
　　Set pvt = pvc.CreatePivotTable(TableDestination:=ws.Name & "!R3C1", _
　　　　　　　　　　　　　　　　　　　　　　TableName:="ﾋﾟﾎﾞｯﾄﾃｰﾌﾞﾙ1", _
　　　　　　　　　　　　　　　　　　　　　　DefaultVersion:=xlPivotTableVersion10)
　　With pvt
　　　　With .PivotFields("担当")
　　　　　　.Orientation = xlRowField
　　　　　　.Position = 1
　　　　End With
　　　　With .PivotFields("分類")
　　　　　　.Orientation = xlColumnField
　　　　　　.Position = 1
　　　　End With
　　　　.AddDataField .PivotFields("金額"), "合計 / 金額", xlSum
　　End With
End Sub

だいぶ理解しやすいのではないかと思います。

Set pvc = ActiveWorkbook.PivotCaches.Add(
ブックにピボットキャッシュを作成しています。

Set pvt = pvc.CreatePivotTable(
ピボットキャッシュにピボットテーブルを作成しています。


Excel2010とExcel2003のピボットテーブルVBAの違いについて

上記のExcel2010とExcel2003のマクロ記録から作成したVBAサンプルコードは、
結局、2010も2003もほぼ同じになりました。
大きく違いうのは、

PivotCaches.Create
と
PivotCaches.Add

この部分と、

DefaultVersion:=xlPivotTableVersion14
と
DefaultVersion:=xlPivotTableVersion10

PivotCachesのAddメソッドは、Excel2010では非表示メンバーとなっています。
非表示メンバーとなっても、Addメソッドは2010でも使用可能となっています。

Excel2003がまだ多く使われていたころであれば、2003の記述をお勧めするところですが、
さすがにもう2003は必要無いと思いますのでで、2010の記述を使えば良いでしょう。


ピボットテーブル（PivotTable）のマクロVBA実践例

VBAでピボットテーブルを扱う時は、事前にピボットテーブルを作成しておき、
必要に応じて、その部分の処理のみVBAで行うようにすることをお勧めします。

ピボットのデータソースの変更

With ActiveSheet
　　.PivotTables("ピボット1").ChangePivotCache ActiveWorkbook.PivotCaches. _
　　　　Create(SourceType:=xlDatabase, SourceData:=.Range("A1").CurrentRegion)
End With

ピボットの更新

ActiveSheet.PivotTables("ピボット1").PivotCache.Refresh



同じテーマ「マクロVBA入門」の記事

第91回.条件付き書式（FormatCondition）
第126回.入力規則（Validation）
第92回.名前定義（Names）
第93回.ピボットテーブル（PivotTable）
第94回.コメント（Comment）
第95回.ハイパーリンク（Hyperlink）
第96回.グラフ（Chart）
第97回.図形オートシェイプ（Shape）
第136回.フォームコントロール
第137回.ActiveXコントロール
第98回.Findメソッド（Find,FindNext,FindPrevious）


新着記事NEW ・・・新着記事一覧を見る

第5章：AI×VBAでつまづかない！トラブルシューティングとAIとの付き合い方 ｜生成AI活用研究(2025-05-20)
第4章：【事例で学ぶ】AIとVBAでExcel作業を劇的に効率化する！ ｜生成AI活用研究(2025-05-20)
第3章：AIを「自分だけのVBA先生」にする！質問・相談の超実践テクニック｜生成AI活用研究(2025-05-19)
第2章 VBAって怖くない！Excelを「言葉で動かす」（超入門）｜生成AI活用研究(2025-05-18)
第1章：AIって一体何？あなたのExcel作業をどう変える？（AI超基本）｜生成AI活用研究(2025-05-18)
AI時代のExcel革命：AI×VBAで“書かない自動化”超入門｜生成AI活用研究(2025-05-17)
Geminiと100本ノック 23本目：シート構成の一致確認｜生成AI活用研究（5月16日）
AIが問う出版の未来は淘汰か進化か：AIと書籍の共存の道とは｜生成AI活用研究(2025-05-16)
Geminiと100本ノック 22本目：FizzBuzz発展問題｜生成AI活用研究（5月15日）
すぐに使える！生成AI プロンプト作成 実践ガイド｜生成AI活用研究(2025-05-15)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得（End,Rows.Count）｜VBA入門
2.繰り返し処理（For Next)｜VBA入門
3.変数宣言のDimとデータ型｜VBA入門
4.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
5.ひらがな⇔カタカナの変換｜エクセル基本操作
6.RangeとCellsの使い方｜VBA入門
7.メッセージボックス(MsgBox関数)｜VBA入門
8.セルのクリア（Clear,ClearContents）｜VBA入門
9.FILTER関数（範囲をフィルター処理）｜エクセル入門
10.条件分岐（Select Case）｜VBA入門



このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。

このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
本文下部へ
同じテーマの記事
新着記事
アクセスランク


↑