VBA100本ノック 12本目：セル結合を解除
セル結合されているセルの結合を解除して、入っていた数値を均等に割り振る問題です。
ツイートでの見やすさを考慮して、ブック・シート指定等を適宜省略しています。
出題
A1から始まる表範囲のC列に金額が入っています。
しかし、ところどころに結合されたセルがあります。
セル結合を解除し、入っている金額を整数で均等に割り振ってください。（2枚目画像）
端数処理方法は任意とします。
※結合セルには正の整数しか入っていません。
https://excel-ubara.com/vba100sample/VBA100_12.xlsm
https://excel-ubara.com/vba100sample/VBA100_12.zip
VBA作成タイム
この下に頂いた回答へのリンクと解説を掲載しています。
途中まででも良いので、できるだけ自分でVBAを書いてみましょう。
他の人の回答および解説を見て、書いたVBAを見直してみましょう。
頂いた回答
解説
MergeArea.Count > 1
これでも判定できます。
結合範囲のセル数が > 1 なら結合されていることになります。
セル結合を解除するには、
Range.MergeCells = False
Range.UnMerge
上はプロパティ、下はメソッドです。
シートやValue等、省略できるものは全て省略しました。
Sub VBA100_12_01()
Dim rng As Range
Dim i As Long, v As Long, m As Long
For i = 2 To Cells(Rows.Count, 3).End(xlUp).Row
Set rng = Cells(i, 3).MergeArea
If rng.Count > 1 Then
rng.UnMerge
v = rng(1)
rng = Int(rng(1) / rng.Count)
m = v - (rng(1) * rng.Count)
rng.Resize(m) = rng(1) + 1
End If
Next
End Sub
四捨五入すると面倒なので、切り捨ててから差分を割り振る方がマイナスにならなくて簡単だと思います。
上では、差分数のResizeした範囲に+1しています。
今回は特に補足もないので省略せずに書き直したVBAだけ掲載しました。
m=０、つまり割り切れてあまりが無い場合の判定が漏れていました。
Sub VBA100_12_01()
Dim rng As Range
Dim i As Long, v As Long, m As Long
For i = 2 To Cells(Rows.Count, 3).End(xlUp).Row
Set rng = Cells(i, 3).MergeArea
If rng.Count > 1 Then
rng.UnMerge
v = rng(1)
rng = Int(rng(1) / rng.Count)
m = v - (rng(1) * rng.Count)
If m <> 0 Then rng.Resize(m) = rng(1) + 1
End If
Next
End Sub
補足
Sub VBA100_12_02()
Dim target As Range
Set target = ActiveSheet.Range("A1").CurrentRegion
Set target = Intersect(target, target.Offset(1, 2))
Dim rng As Range
Dim i As Long, v As Long, m As Long
For Each rng In target
If rng.MergeCells Then
Set rng = rng.MergeArea
rng.UnMerge
v = rng.Item(1)
rng.Value = Int(rng.Item(1) / rng.Count)
m = v - (rng.Item(1) * rng.Count)
If m <> 0 Then rng.Resize(m) = rng.Item(1) + 1
End If
Next
End Sub
最初のVBAとやっていることは同じです。
ForをFor Eachに変更して、あとはプロパティ等を省略せずに少し丁寧に書き直しただけの違いです。
サイト内関連ページ
同じテーマ「VBA100本ノック」の記事
9本目：フィルターコピー
10本目：行の削除
11本目：セル結合の警告
12本目：セル結合を解除
13本目：文字列の部分フォント
14本目：社外秘シート削除
15本目：シートの並べ替え
16本目：無駄な改行を削除
17本目：重複削除（ユニーク化）
18本目：名前定義の削除
19本目：図形のコピー
新着記事NEW ・・・新着記事一覧を見る
究極のVBA転記プロンプト公開！あなたの事務作業を劇的に効率化｜生成AI活用研究(2025-06-02)
エクセル入門 4択クイズ｜エクセル入門(2025-05-31)
VBA入門 4択クイズ｜VBA入門(2025-05-30)
Google Calendar iCal形式で祝日取得｜Excelリファレンス(2025-05-30)
生成AIが拓く「もう一人の自分」とパーソナライゼーションの未来｜生成AI活用研究(2025-05-30)
生成AIパスポート試験 練習問題（四股択一式）｜生成AI活用研究(2025-05-29)
生成AIパスポート試験 キーワード解説｜生成AI活用研究(2025-05-29)
AIと『対話』する時代に問う：あなたの前には誰がいますか？｜生成AI活用研究(2025-05-28)
AI擬人化の光と影：その心理と健全な付き合い方｜生成AI活用研究(2025-05-28)
AI時代の「Hello World」のすすめ：すべてはこの一歩から｜生成AI活用研究(2025-05-27)
アクセスランキング ・・・ ランキング一覧を見る
1.最終行の取得（End,Rows.Count）｜VBA入門
2.変数宣言のDimとデータ型｜VBA入門
3.繰り返し処理（For Next)｜VBA入門
4.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
5.RangeとCellsの使い方｜VBA入門
6.FILTER関数（範囲をフィルター処理）｜エクセル入門
7.メッセージボックス(MsgBox関数)｜VBA入門
8.セルのクリア（Clear,ClearContents）｜VBA入門
9.ブックを閉じる・保存（Close,Save,SaveAs）｜VBA入門
10.マクロとは？VBAとは？VBAでできること｜VBA入門
- ホーム
- マクロVBA入門編
- VBA100本ノック
- 12本目：セル結合を解除
このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。